Article Search

1. トップ
2. サンプル
3. Visual Basic 6.0 (VB6)
4. プロセス (Process)
5. プログラムの終了コードを取得する

プログラムの終了コードを取得する

Option Explicit

' OpenProcess 関数
Private Declare Function OpenProcess Lib "KERNEL32.DLL" ( _
    ByVal dwDesiredAccess As Long, _
    ByVal bInheritHandle  As Long, _
    ByVal dwProcessId     As Long  _
) As Long

' CloseHandle 関数
Private Declare Function CloseHandle Lib "KERNEL32.DLL" ( _
    ByVal hObject As Long _
) As Long

' GetExitCodeProcess 関数
Private Declare Function GetExitCodeProcess Lib "KERNEL32.DLL" ( _
    ByVal hProcess   As Long, _
    ByRef lpExitCode As Long  _
) As Long

' 定数の定義
Private Const PROCESS_QUERY_INFORMATION As Long = &H400
Private Const STILL_EXIT                As Long = &H103

    ' メモ帳を起動して、プロセス ID を取得する
    Dim lProcessId As Long
    lProcessId = CLng(Shell("Notepad", vbNormalFocus))

    ' プロセスのハンドルを取得する
    Dim hProcessHandle As Long
    hProcessHandle = OpenProcess(PROCESS_QUERY_INFORMATION, 0&, lProcessId)

    ' 制御を止めるために、メッセージ ボックスを表示する
    Call MsgBox("このメッセージ ボックスが表示されてる間に終了してください")

    ' 終了コードを取得する
    Dim lExitCode As Long
    Call GetExitCodeProcess(hProcessHandle, lExitCode)

    ' 起動したプログラムが終了したかどうかを判断する
    If lExitCode <> STILL_EXIT Then
        Call MsgBox("終了コードは " & CStr(lExitCode) & " です")
    End If

    ' プロセスのハンドルを閉じる
    Call CloseHandle(hProcessHandle)

スポンサーリンク