Article Search

1. トップ
2. サンプル
3. Visual Basic 6.0 (VB6)
4. 文字列 (String)
5. 文字列の一部をバイト単位で取り出す (LeftB, MidB, RightB)

文字列の一部をバイト単位で取り出す (LeftB, MidB, RightB)

' --------------------------------------------------------------------------------
'       文字列の左端から指定したバイト数分の文字列を返します。
'
' @Param    stTarget    取り出す元になる文字列。
' @Param    iByteSize   取り出すバイト数。
' @Return               左端から指定されたバイト数分の文字列。
' --------------------------------------------------------------------------------
Public Function LeftByte(ByVal stTarget As String, ByVal lByteCount As Long) As String
    LeftByte = StrConv(LeftB$(StrConv(stTarget, vbFromUnicode), lByteCount), vbUnicode)
End Function

' --------------------------------------------------------------------------------
'       文字列の指定されたバイト位置以降のすべての文字列を返します。
'
' @Param    stTarget    取り出す元になる文字列。
' @Param    iStart      取り出しを開始する位置。
' @Return               指定されたバイト位置以降のすべての文字列。
' --------------------------------------------------------------------------------
Public Function MidByte(ByVal stTarget As String, ByVal iStart As Long, Optional ByVal iByteCount As Variant) As String
    If IsMissing(iByteCount) = False Then
        MidByte = StrConv(MidB$(StrConv(stTarget, vbFromUnicode), iStart, iByteCount), vbUnicode)
    Else
        MidByte = StrConv(MidB$(StrConv(stTarget, vbFromUnicode), iStart), vbUnicode)
    End If
End Function

' --------------------------------------------------------------------------------
'       文字列の右端から指定されたバイト数分の文字列を返します。
'
' @Param    stTarget    取り出す元になる文字列。
' @Param    iStart      取り出すバイト数。
' @Return               右端から指定されたバイト数分の文字列。
' --------------------------------------------------------------------------------
Public Function RightByte(ByVal stTarget As String, ByVal iByteCount As Long) As String
    RightByte = StrConv(RightB$(StrConv(stTarget, vbFromUnicode), iByteCount), vbUnicode)
End Function

    ' 必要な変数を宣言する
    Dim stTarget As String
    stTarget = "ＡBＣDＥF"

    ' 左端から 6 バイトの文字列を取得する
    Call MsgBox(LeftByte(stTarget, 6))       'ＡBＣD

    ' 左端から 4 バイト以降のすべての文字列を取得する
    Call MsgBox(MidByte(stTarget, 4))        'ＣDＥF

    ' 左端から 4 バイト目から 5 バイトの文字列を取得する
    Call MsgBox(MidByte(stTarget, 4, 5))     'ＣDＥ

    ' 右端から 3 バイトの文字列を取得する
    Call MsgBox(RightByte(stTarget, 3))      'ＥF

スポンサーリンク